Aplikasi Pencari Web

Aplikasi ini hanyalah aplikasi sederhana yang dibuat untuk pengguna internet agar memudahkan pecarian web di internet seperti menggunakan Google, Yahoo, Bing, dll.

Visual Styler

Visual Styler adalah Kontrol yang digunakan untuk mengubah tampilan dari Form beserta kontrol didalamnya. Tampilannya dapat dirubah menjadi seperti Office, Mac, atau Vista.

Penggunaannya sangat mudah, Anda tinggal menambahkan kontrol Visual Styler ke dalam Form. Lalu pilih tampilan yang diinginkan di properti VisualStyle-nya. Setelah itu simpan Project untuk melakukan perubahan.

Menekan Tombol dengan kode

Berikut cara menekan Tombol / Button menggunakan kode, jadi tanpa melakukan klik menggunakan pointer mouse.

Tulis kode berikut di event '(Declarations)' dari Form
[ VB 6.0 ]

Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

[ VB .NET ]

Private Declare Function SendMessage Lib"user32.dll" Alias "SendMessageA"(ByVal hwnd As Integer, ByVal wMsg As Integer, ByVal wParam As Integer, ByRef lParam As Object) As Integer

Const WM_LBUTTONDOWN = &H201
Const WM_LBUTTONUP = &H202

Sekarang untuk mempraktekkannya gunakan kode seperti berikut :
 [ VB 6.0 ]

SendMessage Command1.hwnd, &HF3, 1, 0
Sleep 150
SendMessage Command1.hwnd, &HF3, 0, 0

Command1.Value = True

[ VB .NET ]

SendMessage(Button1.Handle, WM_LBUTTONDOWN, 0, 0)
Application.DoEvents()
Threading.Thread.Sleep(150)
SendMessage(Button1.Handle, WM_LBUTTONUP, 0, 0)

Button1.PerformClick()

Progress di Taskbar

Cara menambahkan Progress di Taskbar ini hanya bisa diterapkan pada Windows 7 menggunakan VB .NET. Library yang digunakannya adalah WindowsAPICodePack.

Menata Form Child di Form MDI

Jika Anda sedang membuat Project yang menggunakan Form MDI, ada baiknya ditambahkan kode untuk menata Form Child-nya agar terlihat rapi.

• Cascade
  
  Kode :
  [ VB 6.0 ] Me.Arrange vbCascade
  [ VB .NET ] Me.LayoutMdi(MdiLayout.Cascade)
  


• Tile Horizontal
  
  Kode :
  [ VB 6.0 ] Me.Arrange vbTileHorizontal
  [ VB .NET ] Me.LayoutMdi(MdiLayout.TileHorizontal)
  


• Tile Vertical
  
  Kode :
  [ VB 6.0 ] Me.Arrange vbTileVertical
  [ VB .NET ] Me.LayoutMdi(MdiLayout.TileVertical)
  

Untuk mempermudah User untuk menggunakannya, Anda bisa membuat menu khusus seperti ini :

Membulatkan Bilangan Desimal

Banyak cara dalam VB untuk membulatkan suatu bilangan/ angka desimal menjadi bilangan bulat. Jika Anda belum paham, berikut penjelasan singkatnya :

• Pembulatan Otomatis
  Pembulatan ini dilakukan secara otomatis tergantung bilangannya.
  Jika angka utamanya adalah ganjil dan angka desimalnya >= 0,5 maka dilakukan pembulatan ke atas (angka utama ditambah 1) dan bila angka desimalnya < 0,5 maka dilakukan pembulatan ke bawah.
  Namun jika angka utamanya adalah 0 atau genap dan angka desimalnya > 0,5 maka dilakukan pembulatan ke atas dan bila angka desimalnya <= 0,5 maka dilakukan pembulatan ke bawah.
  i = CInt(0.4) , hasilnya 0
  i = CInt(0.5) , hasilnya 0
  i = CInt(0.6) , hasilnya 1
  i = CInt(1.4) , hasilnya 1
  i = CInt(1.5) , hasilnya 2
  i = CInt(1.6) , hasilnya 2
  


• Pembulatan Selalu ke Bawah
  Pembulatan ini dilakukan selalu ke bawah berapapun angka desimalnya. Dengan kata lain akan menghilangkan angka desimalnya.
  i = Int(1.1) , hasilnya 1
  i = Int(1.5) , hasilnya 1
  i = Int(1.8) , hasilnya 1
  


• Pembulatan Selalu ke Atas
  Pembulatan ini dilakukan selalu ke atas berapapun angka desimalnya.
  i = -Int(-(1.1)) , hasilnya 2
  i = -Int(-(1.5)) , hasilnya 2
  i = -Int(-(1.8)) , hasilnya 2


• Pembulatan Yang Ditentukan
  Pembulatan ini dilakukan sesuai dengan Batas yang telah ditentukan.
  Jadi bila angka desimalnya >= Batas maka dilakukan pembulatan ke atas dan bila angka desimalnya < Batas maka dilakukan pembulatan ke bawah.
  Misalnya Batas yang ditentukan adalah 0,4 kodenya seperti ini :
  
  Dim Nilai As Double, Hasil As Long
  
  Nilai = 1.4 'bilangan yg akan dibulatkan
  
  Hasil = Int(Nilai) + IIf(CDbl(CStr(Nilai - Int(Nilai))) >= 0.4, 1, 0) 'Batas = 0,4
  
  MsgBox Hasil 'pesan Hasil = 2

Menghitung Selisih Tanggal

Bila Anda membutuhkan kode untuk menghitung selisih antar 2 data Tanggal baik secara hari, bulan, atau tahun, berikut contohnya :

Fungsi : DateDiff( Jenis Interval, Tanggal Pertama, Tanggal Kedua )

Jenis Interval	Keterangan
d	Day (Hari)
m	Month (Bulan)
yyyy	Year (Tahun)
h	Hour (Jam)

n	Minute (Menit)
s	Second (Detik)
ww	Week (Minggu)
q	Quater (4 Bulan)

Misalnya Anda ingin menghitung selisih hari antara tanggal 15 Jan 2012 (ditulis #1/15/2012#) dan 20 Jan 2012, yang berarti akan menggunakan jenis interval "d".
t = DateDiff("d", #1/15/2012#, #1/20/2012#) , hasilnya 5

Jika Tanggal didapat dari kontrol semisal DateTimePicker, maka kodenya :
t = DateDiff("d", DateTimePicker1.Value, DateTimePicker2.Value)

Menambah dan Mengurangi Tanggal

Untuk menambah dan mengurangi data bertipe Date/Tanggal tidak semudah dengan data bertipe Angka yang hanya menggunakan operator + dan -. Karena itu ada fungsi khusus untuk melakukannya, berikut contoh penggunaannya :

Fungsi : DateAdd( Jenis interval, Besar perubahan, Tanggal yang dihitung )

Jenis Interval	Keterangan
d	Day (Hari)
m	Month (Bulan)
yyyy	Year (Tahun)

h	Hour (Jam)
n	Minute (Menit)
s	Second (Detik)
ww	Week (Minggu)
q	Quater (4 Bulan)

Misalnya Anda ingin menghitung 2 hari setelah tanggal 15 Jan 2012 (ditulis #1/15/2012#), yang berarti akan menggunakan jenis interval "d" dan besar perubahannya adalah 2
t = DateAdd("d", 2, #1/15/2012#) , hasilnya 17 Jan 2012

Sekarang jika Anda ingin menghitung 3 bulan sebelumnya, yang berarti akan menggunakan jenis interval "m" dan besar perubahaanya adalah -3.
t = DateAdd("m", -3, #1/15/2012#) , hasilnya 15 Okt 2011

Jika Tanggal didapat dari kontrol semisal DateTimePicker, maka kodenya :
DateTimePicker2.Value = DateAdd("m", -3, DateTimePicker1.Value)

Fungsi-fungsi Date/Time

Berikut ini merupakan Fungsi-fungsi dasar untuk mengolah data jenis Date/Time atau Tanggal/Waktu di Visual Basic

• Now, digunakan untuk mendapatkan Tanggal dan Waktu sekarang.
  d = Now , hasilnya 13/01/2012 1:22:42


• Date, digunakan untuk mendapatkan Tanggal sekarang.
  [ VB 6.0 ] d = Date , hasilnya 13/01/2012
  [ VB .NET ] d = Now.Date , hasilnya 13/01/2012


• Time, digunakan untuk mendapatkan Waktu sekarang.
  [ VB 6.0 ] d = Time , hasilnya 1:22:42
  [ VB .NET ] d = Now.ToLongTimeString , hasilnya 1:22:42


• Day(x), digunakan untuk mengambil nilai Tanggal saja dari x.
  [ VB 6.0 ] d = Day(#1/13/2012#) , hasilnya 13
  [ VB .NET ] d = #1/13/2012#.Day , hasilnya 13


• Month(x), digunakan untuk mengambil nilai Bulan saja dari x.
  [ VB 6.0 ] d = Month(#1/13/2012#) , hasilnya 1
  [ VB .NET ] d = #1/13/2012#.Month , hasilnya 1


• Year(x), digunakan untuk mengambil nilai Tahun saja dari x.
  [ VB 6.0 ] d = Year(#1/13/2012#) , hasilnya 2012
  [ VB .NET ] d = #1/13/2012#.Year , hasilnya 2012


• Hour(x), digunakan untuk mengambil nilai Jam saja dari x.
  [ VB 6.0 ] d = Hour(#1:22:42 AM#) , hasilnya 1
  [ VB .NET ] d = #1:22:42 AM#.Hour , hasilnya 1


• Minute(x), digunakan untuk mengambil nilai Menit saja dari x.
  [ VB 6.0 ] d = Minute(#1:22:42 AM#) , hasilnya 22
  [ VB .NET ] d = #1:22:42 AM#.Minute, hasilnya 22


• Second(x), digunakan untuk mengambil nilai Detik saja dari x.
  [ VB 6.0 ] d = Second(#1:22:42 AM#) , hasilnya 42
  [ VB .NET ] d = #1:22:42 AM#.Second, hasilnya 42


• DateSerial(x, y, z), digunakan untuk menghasilkan Tanggal dari kombinasi x, y, z.
  d = DateSerial(2012, 1, 13) , hasilnya 13/01/2012


• TimeSerial(x, y, z), digunakan untuk menghasilkan Waktu dari kombinasi x, y, z.
  d = TimeSerial(1, 22, 42) , hasilnya 1:22:42


• MonthName(x), digunakan untuk mendapatkan nama Bulan dari x.
  d = MonthName(2) , hasilnya Februari


• WeekdayName(x), digunakan untuk mendapatkan nama Hari dari x.
  d = WeekdayName(2, , vbSunday) , hasilnya Senin

Untuk kegunaan Fungsi-fungsi Date/Time yang lain, Anda bisa melihat postingan ini :
Nama Hari dari Tanggal
Menambah dan Mengurangi Tanggal
Menghitung Selisih Tanggal

CrystalReport Tanpa Database

Tidak selamanya penggunaan CrystalReport harus menggunakan Database. Berikut ini contoh penerapannya dalam aplikasi pembuatan Kartu Nama.

Text Berjalan di Desktop

Berikut ini contoh dasar untuk membuat Text yang berjalan di Desktop komputer. Source code ini merupakan pengembangan dari aplikasi desktop sebelumnya.

Mengganti Warna Border dari Kontrol

Kontrol-kontrol yang ada di VB tidak menyediakan properti untuk mengganti warna bordernya. Jadi jika Anda ingin mengubah warna bordernya diperlukan kode tambahan.
Cara pembuatannya seperti di bawah ini :

Buat Project baru dengan sebuah Form dan sebuah Module didalamnya.
Di Module ketikkan kode berikut :

[ VB 6.0 ]

Private Declare Function CreateRectRgn Lib "gdi32.dll" (ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Declare Function SetWindowRgn Lib "user32.dll" (ByVal hwnd As Long, ByVal hRgn As Long, ByVal bRedraw As Boolean) As Long
Private Declare Function CreateSolidBrush Lib "gdi32.dll" (ByVal crColor As Long) As Long
Private Declare Function FrameRgn Lib "gdi32.dll" (ByVal hDC As Long, ByVal hRgn As Long, ByVal hBrush As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long

Public Sub BorderColor(ByVal Ctl As Control, ByVal lColor As OLE_COLOR, Optional ByVal BorderWidth As Integer = 2)
    Dim l As Long
   
    l = CreateRectRgn(BorderWidth, BorderWidth, (Ctl.Width / Screen.TwipsPerPixelX) - BorderWidth, (Ctl.Height / Screen.TwipsPerPixelY) - BorderWidth)
    SetWindowRgn Ctl.hwnd, l, False

    l = CreateRectRgn(Ctl.Left / Screen.TwipsPerPixelX, Ctl.Top / Screen.TwipsPerPixelY, Ctl.Width / Screen.TwipsPerPixelX + (Ctl.Left / Screen.TwipsPerPixelX), Ctl.Height / Screen.TwipsPerPixelY + (Ctl.Top / Screen.TwipsPerPixelY))
    FrameRgn Ctl.Container.hDC, l, CreateSolidBrush(lColor), BorderWidth, BorderWidth
End Sub

[ VB .NET ]

Private Declare Function CreateRectRgn Lib "gdi32.dll" (ByVal X1 As Integer, ByVal Y1 As Integer, ByVal X2 As Integer, ByVal Y2 As Integer) As Integer
Private Declare Function SetWindowRgn Lib "user32" (ByVal hwnd As Integer, ByVal hRgn As Integer, ByVal bRedraw As Boolean) As Integer
Private Declare Function CreateSolidBrush Lib "gdi32.dll" (ByVal crColor As Integer) As Integer
Private Declare Function GetDC Lib "user32.dll" (ByVal hwnd As Integer) As Integer
Private Declare Function FrameRgn Lib "gdi32.dll" (ByVal hdc As Integer, ByVal hRgn As Integer, ByVal hBrush As Integer, ByVal nWidth As Integer, ByVal nHeight As Integer) As Integer

Public Sub BorderColor(ByVal Ctl As Control, ByVal lColor As Color, Optional ByVal BorderWidth As Integer = 1)
        Dim i As Integer

        i = CreateRectRgn(BorderWidth, BorderWidth, Ctl.Width - BorderWidth, Ctl.Height - BorderWidth)
        SetWindowRgn(Ctl.Handle, i, False)

        i = CreateRectRgn(Ctl.Left, Ctl.Top, Ctl.Width + Ctl.Left, Ctl.Height + Ctl.Top)
        FrameRgn(GetDC(Ctl.Parent.Handle), i, CreateSolidBrush(CInt(ColorTranslator.ToWin32(lColor))), BorderWidth, BorderWidth)
End Sub

Sekarang buatlah sebuah TextBox di Form1 dan misalnya Anda ingin diubah warna bordernya menjadi warna biru, maka tuliskan kode berikut ini di bagian 'Form_Paint' dari Form1 :
[ VB 6.0 ]

BorderColor Text1, vbBlue

[ VB .NET ]

BorderColor(TextBox1, Color.Blue)

CATATAN :
- Bagi pengguna VB 6.0,  apabila Kontrol yang akan diganti warna bordernya ditempatkan di PictureBox, maka properti "AutoRedraw" dari PicturBox tersebut harus bernilai "True".
- Bagi pengguna VB 6.0,  apabila Kontrol yang akan diganti warna bordernya ditempatkan di Frame atau Tab, maka cara diatas tidak dapat digunakan. Solusinya buatlah sebuah PictureBox (properti AutoRedraw=True; BorderStyle=0) ke dalam Frame atau Tab tersebut, baru Kontrol yang akan diganti warna bordernya ditempatkan di PictureBox tersebut.

Menghilangkan Border dari Kontrol

Tidak semua Kontrol yang ada di VB menyediakan properti untuk menghilangkan border / pinggiran-nya. Karena itu perlu dibuat kode khusus untuk menghilangkan border tersebut. Berikut contoh pembuatannya :

Buat Project baru dengan sebuah Form dan sebuah Module didalamnya.
Di Module ketikkan kode berikut :

[ VB 6.0 ]

Private Declare Function CreateRectRgn Lib "gdi32.dll" (ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
Private Declare Function SetWindowRgn Lib "user32" (ByVal hwnd As Long, ByVal hRgn As Long, ByVal bRedraw As Boolean) As Long

Public Sub NoBorder(ByVal Ctl As Control, Optional ByVal CropWidth As Integer = 2)
    Dim l As Long
    l = CreateRectRgn(CropWidth, CropWidth, (Ctl.Width / Screen.TwipsPerPixelX) - CropWidth, (Ctl.Height / Screen.TwipsPerPixelY) - CropWidth)
    SetWindowRgn Ctl.hwnd, l, False
End Sub

[ VB .NET ]

Private Declare Function CreateRectRgn Lib "gdi32.dll" (ByVal X1 As Integer, ByVal Y1 As Integer, ByVal X2 As Integer, ByVal Y2 As Integer) As Integer
Private Declare Function SetWindowRgn Lib "user32" (ByVal hwnd As Integer, ByVal hRgn As Integer, ByVal bRedraw As Boolean) As Integer

Public Sub NoBorder(ByVal Ctl As Control, Optional ByVal CropWidth As Integer = 1)
    Dim i As Integer
    i = CreateRectRgn(CropWidth, CropWidth, Ctl.Width - CropWidth, Ctl.Height - CropWidth)
    SetWindowRgn(Ctl.Handle, i, False)
End Sub

Sekarang untuk percobaanya buat beberapa Kontrol ke dalam Form. Lalu ketikkan kode sesuai dengan nama Kontrol-nya di bagian 'Form_Load' dari Form seperti ini :

NoBorder TextBox1 'nama kontolnya adlh TextBox1

Fungsi Semua Terisi

Fungsi Semua Terisi ini adalah fungsi untuk memudahkan Anda apakah User telah mengisi seluruh kontrol isian (seperti TextBox atau ComboBox) dalam suatu Form. Agar lebih jelas, berikut cara membuatnya :

Buat Project baru dengan sebuah Form dan sebuah Module didalamnya.
Di Module ketikkan kode berikut :

Public Function SemuaTerisi(ByVal Frm As Form) As Boolean
    Dim c As Control
    Dim b As Boolean
  
    b = True
  
    For Each c In Frm.Controls
        If (TypeOf c Is TextBox) Or (TypeOf c Is ComboBox) Then 'utk TextBox dan ComboBox
           b = Not (Trim(c.Text) = "")
        End If
      
        If b = False Then
            c.SetFocus
            Exit For
        End If
    Next
  
    SemuaTerisi = b
End Function

(bagi pengguna VB .NET gantikan kode yang berwarna merah dengan kode "c.Focus()"

Untuk percobaan, buatlah 3 buah Textbox dan 1 Tombol/ Button ke dalam Form. Lalu ketikkan kode berikut di Tombol/ Button_Click :

If SemuaTerisi(Me) Then
    MsgBox "Data sudah lengkap", vbInformation
Else
    MsgBox "Data belum lengkap", vbCritical
End If

Jalankan, kemudian tes dengan mengisi atau mengosongkan TextBox.

Form Ber-Icon Animasi

Secara default, properti Icon di Form hanya bisa diisi file gambar *.ico dan tidak bisa diisi file gambar gerak / animasi seperti *.gif. Tapi dengan sedikit trik, hal ini bisa dilakukan.

Awal Kapital Otomatis di TextBox

Yang dimaksud disini adalah dimana ketika User mengetikkan suatu kalimat di TextBox, maka secara otomatis huruf pertama setiap kata dalam kalimat tersebut diubah menjadi huruf kapital / besar. Cara ini berguna untuk mempermudah pengisian dan mengurangi resiko kesalahan pengetikan pada TextBox tertentu, seperti TextBox untuk mengisi nama orang.
Caranya buat sebuah kontrol TextBox ke dalam Form. Lalu ketikkan kode berikut :

[ VB 6.0 ]
Di bagian 'Text1_Change' :

Dim i As Integer
i = Text1.SelStart
Text1.Text = StrConv(Text1.Text, vbProperCase)
Text1.SelStart = i

[ VB .NET ]
Di bagian 'TextBox1_TextChanged' :

Dim i As Integer = TextBox1.SelectionStart
TextBox1.Text = StrConv(TextBox1.Text, VbStrConv.ProperCase)
TextBox1.SelectionStart = i

Jalankan, kemudian ketikkan beberapa kata dalam TextBox tersebut.

Performance Counter

Aplikasi ini adalah aplikasi penghitung performance atau kinerja komputer secara real-time yang akan menghitung performance meliputi processor, memory, dan network.
Dalam pembuatannya menggunakan kontrol PerformanceCounter sebagai kontrol utamanya dan tanpa menggunakan Fungsi API. Kontrol PerformanceCounter itu sendiri adalah kontrol yang digunakan untuk mendapatkan nilai kinerja bagian-bagian komputer, seperti processor, memory, local disk, server, network, process, dll.

FileSystemWatcher

FileSystemWatcher adalah sebuah kontrol yang digunakan untuk me-monitor / memantau aktifitas yang terjadi di suatu Folder, seperti membuat, merubah, menghapus File maupun Folder. Penggunaannya sangat mudah, berikut contoh caranya :

• Buat Project baru dengan sebuah Form didalamnya. Masukkan 1 kontrol FileSystemWatcher ke dalam Form tersebut.
• Pilih Folder mana yang akan di monitor dengan mengubah properti "Path"-nya.
• Jika proses monitor ingin dilakukan juga pada Folder di dalam Folder terpilih, ubah properti "IncludeSubdirestories" menjadi "True".
• Sekarang untuk menampung hasilnya, tambahkan 1 kontrol ListBox ke dalam Form.
• Ketikkan kode :
  Di bagian 'FileSystemWatcher1_Changed'
  
  ListBox1.Items.Add("Dirubah > " & e.FullPath)
  Di bagian 'FileSystemWatcher1_Created'
  
  ListBox1.Items.Add("Dibuat > " & e.FullPath)
  Di bagian 'FileSystemWatcher1_Deleted'
  
  ListBox1.Items.Add("Dihapus > " & e.FullPath)
  Di bagian 'FileSystemWatcher1_Renamed'
  
  ListBox1.Items.Add("Diganti namanya > " & e.FullPath)

Sekarang jalankan Project, lalu buat percobaan dengan melakukan aktifitas seperti membuat dan menghapus File atau Folder.

Menjalankan dan Menunggu Aplikasi Ditutup

Yang dimaksud disini adalah proses dimana aplikasi Anda menjalankan sebuah aplikasi lain (dengan kode), lalu aplikasi Anda berhenti dan menunggu sampai aplikasi yang dijalankan tadi ditutup / diakhiri. Berikut ini contoh pembuatannya.
Buat Project baru dengan sebuah Form didalamnya, lalu tambahkan sebuah kontrol Tombol / Button ke Form tersebut.

[ VB 6.0 ]
Di bagian '(Declarations)' dari Form ketikkan :

Private Declare Function OpenProcess Lib "kernel32.dll" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Private Declare Function WaitForSingleObject Lib "kernel32.dll" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Const SYNCHRONIZE = &H100000

Di bagian 'Command1_Click' ketikkan :

Dim l As Long
  
l = Shell("notepad.exe", vbNormalFocus) 'menjalankan aplikasi notepad
l = OpenProcess(SYNCHRONIZE, 0, l)
  
Me.Hide 'menyembunyikan form
  
WaitForSingleObject l, -1  'proses menunggu
  
Me.Show 'memunculkan form kembali

Untuk kelancaran prosesnya, buatlah Project menjadi aplikasi (*.exe)




[ VB .NET ]
Di bagian 'Button1_Click' ketikkan :

Dim p As New Diagnostics.Process
p = Diagnostics.Process.Start("notepad.exe") 'menjalankan aplikasi notepad

Me.Hide() 'menyembunyikan form

p.WaitForExit(-1) 'proses menunggu

Me.Show() 'memunculkan form kembali

Splash Screen

Splash Screen merupakan suatu istilah bagi Form hiasan yang ditampilkan sebelum Form utama ditampilkan. Proses pembuatannya sangat mudah, berikut caranya :

• Buat Project baru dengan dua buah Form didalamnya (Form1 dan Form2). Dalam hal ini Form1 dianggap sebagai Form splash screen-nya, dan Form2 sebagai Form utamanya.


• Atur properti dari Form1, yaitu :
  [ VB 6.0 ] / [ VB .NET ]
  BorderStyle / FormBorderStyle = None
  StartUpPosition / StartPosition = CenterScreen
  ShowInTaskbar = False


• Untuk mempercantik tampilan, tambahkan gambar dan informasi aplikasi ke dalam Form1 seperti gambar diatas.


• [ VB 6.0 ]
  Lalu didalam Form1 masukkan sebuah kontrol Timer(properti Enabled=True; Interval=2000), dan ketikkan kode ini di bagian 'Timer1_Timer'
  
  Form2.Show 'memunculkan form utama
  Unload Me 'menutup form splash
  
  
  
  [ VB .NET ]
  Buka jendela Properties dari Project (klik menu Project > NamaProject Properties).
  Atur nilai "Startup Form" menjadi Form2, dan "Splash Screen" menjadi Form1.
  
  
  Sekarang untuk mengatur ulang waktu lamanya, di jendela "Solution Explorer" klik tombol "Show All Files" lalu cari dan buka file Application.Designer.vb.
  
  
  Lalu gantikan kode (area paling bawah) yang tadinya seperti ini :
  Protected Overrides Sub OnCreateSplashScreen()
      Me.SplashScreen = Global.WindowsApplication1.Form1
  End Sub
  Menjadi seperti ini :
  Protected Overrides Sub OnCreateSplashScreen()
      Me.MinimumSplashScreenDisplayTime = 3000 '3 detik
      Me.SplashScreen = Global.WindowsApplication1.Form1
  End Sub